vlookup函数是一个非常强大的函数，在办公中会经常使用到，根据使用的情况可以做到不一样的效果，使用方便。很多用户不知道怎么使用，下面来看看想想的使用方法吧。

　　vlookup函数的使用方法及实例

　　（一）vlookup 的作用

　　vlookup 用于查找指定值所对应的另一个值。例如：查找某件产品的价格，某个同学的某科成绩等。

　　（二）vlookup 函数表示：

　　=vlookup(要查找的值，查找区域，返回值所在列号，精确匹配或近似匹配)

　　参数说明：

　　1、要查找的值：可以引用单元格的值，例如 B6;也可以直接输入，例如“红色T恤”。

　　2、查找区域：用于指定查找范围，例如 A2:D10。

　　3、返回值所在列号：用于指定返回值在哪列，列号开始必须从指定范围算起;例如指定范围为 B2:E8，则 B 列为第一列，若返回值所在列号为 3，则从 D 列中返回值。

　　4、精确匹配或近似匹配：精确匹配用 0 或 False 表示;近似匹配用 1 或 True 表示;为“可选”项，即可填可不填;若不填，则默认值为近似匹配。

　　（三）vlookup 函数使用方法：

　　1. 基本用法

　　参数介绍

　　VLOOKUP(找什么，在哪找，找到后返回其右侧对应的第几列数据，精确还是模糊查找)

　　注意：

　　需要说明的一点是，Excel中的帮助信息也有错误，比如在插入函数功能中VLOOKUP第四参数的说明就是错的，大家注意不要被误导哦!如下图：

　　2. 单条件查找

　　在E2单元格输入=VLOOKUP(D2,$A$2:$B$12,2,0)

　　参数解释：

　　=VLOOKUP(要查找的销售员,包含销售员和其销售额的数据源区域,找到后返回第2列,精确查找)

　　第一参数：找什么(或者说按什么查找)，按销售员查找，所以输入D2

　　第二参数：在哪找，数据源区域在A:B列，所以输入$A$2:$B$12

　　第三参数：找到后返回第几列，我们要查找的是销售额，销售额位于B列，即第二参数中的第二列，所以输入2

　　第四参数：这里要精确查找，所以输入0

　　3. 借助名称框查找

　　选择A2:B12区域定义为查找区域，在E2单元格输入=VLOOKUP(D2,查找区域,2,0)

　　注意：

　　利用名称框抓取数据区域，就不用在手工去选择区域(名称框适用于工作簿中所有的工作表)

　　4. 查找返回多列数据

　　要求：

　　左侧表格是数据源区域，需要在右侧区域根据姓名调取对应的数据，黄色区域是需要填写公式的区域

　　选中H2:K5单元格区域，输入以下公式=VLOOKUP($G2,$A$2:$E$9,COLUMN(B1),0)后按Ctrl+Enter组合键

　　5. 多条件查找（一对多查找）

　　首先在A列增加辅助列，利用COUNT与&组合，在A2输入=C2&COUNTIF($C$2:C2,C2)

　　选择F9:H15单元格输入=VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0)，再按Ctrl+Enter

　　最后为避免出现错误值，要在外面加上IFERROR函数，=IFERROR(VLOOKUP($F$2&ROW($A1),$A$2:$D$15,COLUMN(B$1),0),"")

　　6. 从右到左查找（反向查找）

　　要求：

　　需要按照给出的编号查找对应的销售员姓名，黄色区域输入公式

　　数据源格式不允许改动时

　　在F2单元格输入=VLOOKUP(E2,IF({1,0},$B$2:$B$12,$A$2:$A$12),2,0)

　　此处IF函数，重新构建了一个区域，将$B$2:$B$12放到第一列，$A$2:$A$12放到第二列，查找并返回对应数据

　　当IF的第一参数是{1,0}时，相当于把条件成立的和不成立的放到一起，构建为一个内存数组，1代表条件成立的时候，0代表条件不成立的时候，{1,0}形成2列，相当于B列与A列互换位置

　　7. 区间查询

　　要求：

　　需要按照等级划分规则，将成绩划分到其对应的等级中

　　建立辅助列

　　注意：必须是升序排列

　　此函数的最后一个参数可以隐藏(不输入)，或者输入1

　　在C2单元格输入 =VLOOKUP(B2,$I$2:$J$5,2)，将此公式展开是这样的： =VLOOKUP(B2,{0,"D";60,"C";80,"B";90,"A"},2)

　　8. 通配符模糊查找

　　此方法只适用于有唯一一个符合条件的值，否则用SUMIF比较好

　　以上就是为各位用户带来的vlookup函数的使用方法及实例详细内容了。